[PATCH] font-util 1.1.0: Add new macros to replace code common to many font modules
Alan Coopersmith
alan.coopersmith at sun.com
Tue Oct 6 22:32:08 PDT 2009
XORG_FONT_MACROS_VERSION(required-version)
XORG_FONT_CHECK_ENCODING(encoding)
XORG_FONT_CHECK_ENCODING_LIST(encoding1 encoding2....)
XORG_FONT_REQUIRED_PROG(VARNAME, progname)
XORG_FONT_FCCACHE()
XORG_FONT_COMMON_UTILS()
XORG_FONT_BDF_UTILS()
XORG_FONT_SCALED_UTILS()
XORG_FONT_CHECK_COMPRESSION()
XORG_FONT_UCS2ANY()
XORG_FONTDIR(subdir)
Signed-off-by: Alan Coopersmith <alan.coopersmith at sun.com>
---
Changes since previous patch sent for review:
Install fonts & encoding files to ${datadir}/fonts/X11/... by default.
Save the setting of --with-fontparentdir from font-utils ./configure in
fontutil.pc for querying by font modules.
Set default font directory for font modules to the first found from the list:
--with-fontparentdir
pkg-config --variable=fontdir fontutil
${datadir}/fonts/X11
Added XORG_FONT_MACROS_VERSION that works like the code in xorg-macros it
was copied from. (Required moving fontutil.m4 to fontutil.m4.in so that
package version can be substituted from configure.ac automatically.)
Replaced the long list of encodings check macros with a generator macro
and a loop-over-list macro.
(Verified the configure script generated has the same output with either one
as with the old macros, except for the number of blank lines.)
Added XORG_FONT_UCS2ANY to combine the UCS2ANY program check with the
check for the encoding data files it uses.
COPYING | 29 ++++++
README | 5 +
configure.ac | 16 +++-
fontutil.m4 | 227 ------------------------------------------
fontutil.m4.in | 300 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++
fontutil.pc.in | 3 +
6 files changed, 349 insertions(+), 231 deletions(-)
delete mode 100644 fontutil.m4
create mode 100644 fontutil.m4.in
diff --git a/COPYING b/COPYING
index 9ce7238..9582c12 100644
--- a/COPYING
+++ b/COPYING
@@ -95,3 +95,32 @@ supplied in this file in the creation of products supporting the
Unicode Standard, and to make copies of this file in any form for
internal or external distribution as long as this notice remains
attached.
+
+ ------------------------------------------------------------------------
+
+Copyright 2009 Sun Microsystems, Inc. All rights reserved.
+
+Permission is hereby granted, free of charge, to any person obtaining a
+copy of this software and associated documentation files (the
+"Software"), to deal in the Software without restriction, including
+without limitation the rights to use, copy, modify, merge, publish,
+distribute, and/or sell copies of the Software, and to permit persons
+to whom the Software is furnished to do so, provided that the above
+copyright notice(s) and this permission notice appear in all copies of
+the Software and that both the above copyright notice(s) and this
+permission notice appear in supporting documentation.
+
+THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS
+OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
+MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT
+OF THIRD PARTY RIGHTS. IN NO EVENT SHALL THE COPYRIGHT HOLDER OR
+HOLDERS INCLUDED IN THIS NOTICE BE LIABLE FOR ANY CLAIM, OR ANY SPECIAL
+INDIRECT OR CONSEQUENTIAL DAMAGES, OR ANY DAMAGES WHATSOEVER RESULTING
+FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN ACTION OF CONTRACT,
+NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF OR IN CONNECTION
+WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
+
+Except as contained in this notice, the name of a copyright holder
+shall not be used in advertising or otherwise to promote the sale, use
+or other dealings in this Software without prior written authorization
+of the copyright holder.
diff --git a/README b/README
index 68f9af1..4de8bdd 100644
--- a/README
+++ b/README
@@ -1,5 +1,10 @@
X.Org font package creation/installation utilities
+If the --with-fontparentdir option is specified when configuring this
+package, it will be recorded in the fontutil pkg-config file to be used
+as the default parent directory for font modules built using the fontutil
+macros from version 1.1 or later of this package.
+
All questions regarding this software should be directed at the
Xorg mailing list:
diff --git a/configure.ac b/configure.ac
index 962bcaf..e74f650 100644
--- a/configure.ac
+++ b/configure.ac
@@ -22,7 +22,7 @@ dnl
dnl Process this file with autoconf to create configure.
AC_PREREQ([2.57])
-AC_INIT(font-util, [1.0.2], [https://bugs.freedesktop.org/enter_bug.cgi?product=xorg], font-util)
+AC_INIT(font-util, [1.1.0], [https://bugs.freedesktop.org/enter_bug.cgi?product=xorg], font-util)
AM_INIT_AUTOMAKE([foreign dist-bzip2])
AM_MAINTAINER_MODE
@@ -36,10 +36,18 @@ XORG_DEFAULT_OPTIONS
AC_PROG_CC
AC_PROG_INSTALL
-mapdir=${libdir}/X11/fonts/util
+fontdir='${datadir}/fonts/X11'
+AC_ARG_WITH(fontparentdir, AC_HELP_STRING([--with-fontparentdir=<pathname>],
+ [Path to parent of font subdirectories (default: ${datadir}/fonts/X11)]),
+ [fontdir="${withval}"])
+FONTDIR="${fontdir}"
+AC_SUBST(FONTDIR)
+
+mapdir='${fontdir}/util'
AC_ARG_WITH(mapdir, AC_HELP_STRING([--with-mapdir=<pathname>],
- [Path to install font maps]), [mapdir="$withval"])
+ [Path to install font maps (default: <fontparentdir>/util)]),
+ [mapdir="${withval}"])
MAPDIR="$mapdir"
AC_SUBST(MAPDIR)
-AC_OUTPUT([Makefile fontutil.pc])
+AC_OUTPUT([Makefile fontutil.m4 fontutil.pc])
diff --git a/fontutil.m4 b/fontutil.m4
deleted file mode 100644
index 3d22990..0000000
--- a/fontutil.m4
+++ /dev/null
@@ -1,227 +0,0 @@
-dnl Copyright 2005 Red Hat, Inc
-dnl
-dnl Permission to use, copy, modify, distribute, and sell this software and its
-dnl documentation for any purpose is hereby granted without fee, provided that
-dnl the above copyright notice appear in all copies and that both that
-dnl copyright notice and this permission notice appear in supporting
-dnl documentation.
-dnl
-dnl The above copyright notice and this permission notice shall be included
-dnl in all copies or substantial portions of the Software.
-dnl
-dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS
-dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
-dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.
-dnl IN NO EVENT SHALL THE OPEN GROUP BE LIABLE FOR ANY CLAIM, DAMAGES OR
-dnl OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,
-dnl ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR
-dnl OTHER DEALINGS IN THE SOFTWARE.
-dnl
-dnl Except as contained in this notice, the name of the copyright holders shall
-dnl not be used in advertising or otherwise to promote the sale, use or
-dnl other dealings in this Software without prior written authorization
-dnl from the copyright holders.
-dnl
-
-# XORG_FONT_CHECK_{maps}()
-# ------------------------
-# These macros add --enable/disable-{maps} where {maps} are ISO8859-*,
-# JISX0201 or KOI8_R. By default, they are all enabled.
-
-AC_DEFUN([XORG_FONT_CHECK_ISO8859_1],[
- AC_ARG_ENABLE(iso8859-1,
- AS_HELP_STRING([--disable-iso8859-1],
- [Build ISO8859-1 fonts (default: yes)]),
- [ISO8859_1=$enableval],
- [ISO8859_1=yes])
- AC_MSG_CHECKING([whether to build ISO8859-1 fonts])
- AC_MSG_RESULT([$ISO8859_1])
- AM_CONDITIONAL(ISO8859_1, [test "x$ISO8859_1" = xyes])
-])
-
-AC_DEFUN([XORG_FONT_CHECK_ISO8859_2],[
- AC_ARG_ENABLE(iso8859-2,
- AS_HELP_STRING([--disable-iso8859-2],
- [Build ISO8859-2 fonts (default: yes)]),
- [ISO8859_2=$enableval],
- [ISO8859_2=yes])
- AC_MSG_CHECKING([whether to build ISO8859-2 fonts])
- AC_MSG_RESULT([$ISO8859_2])
- AM_CONDITIONAL(ISO8859_2, [test "x$ISO8859_2" = xyes])
-])
-
-AC_DEFUN([XORG_FONT_CHECK_ISO8859_3],[
- AC_ARG_ENABLE(iso8859-3,
- AS_HELP_STRING([--disable-iso8859-3],
- [Build ISO8859-3 fonts (default: yes)]),
- [ISO8859_3=$enableval],
- [ISO8859_3=yes])
- AC_MSG_CHECKING([whether to build ISO8859-3 fonts])
- AC_MSG_RESULT([$ISO8859_3])
- AM_CONDITIONAL(ISO8859_3, [test "x$ISO8859_3" = xyes])
-])
-
-AC_DEFUN([XORG_FONT_CHECK_ISO8859_4],[
- AC_ARG_ENABLE(iso8859-4,
- AS_HELP_STRING([--disable-iso8859-4],
- [Build ISO8859-4 fonts (default: yes)]),
- [ISO8859_4=$enableval],
- [ISO8859_4=yes])
- AC_MSG_CHECKING([whether to build ISO8859-4 fonts])
- AC_MSG_RESULT([$ISO8859_4])
- AM_CONDITIONAL(ISO8859_4, [test "x$ISO8859_4" = xyes])
-])
-
-AC_DEFUN([XORG_FONT_CHECK_ISO8859_5],[
- AC_ARG_ENABLE(iso8859-5,
- AS_HELP_STRING([--disable-iso8859-5],
- [Build ISO8859-5 fonts (default: yes)]),
- [ISO8859_5=$enableval],
- [ISO8859_5=yes])
- AC_MSG_CHECKING([whether to build ISO8859-5 fonts])
- AC_MSG_RESULT([$ISO8859_5])
- AM_CONDITIONAL(ISO8859_5, [test "x$ISO8859_5" = xyes])
-])
-
-AC_DEFUN([XORG_FONT_CHECK_ISO8859_6],[
- AC_ARG_ENABLE(iso8859-6,
- AS_HELP_STRING([--disable-iso8859-6],
- [Build ISO8859-6 fonts (default: yes)]),
- [ISO8859_6=$enableval],
- [ISO8859_6=yes])
- AC_MSG_CHECKING([whether to build ISO8859-6 fonts])
- AC_MSG_RESULT([$ISO8859_6])
- AM_CONDITIONAL(ISO8859_6, [test "x$ISO8859_6" = xyes])
-])
-
-AC_DEFUN([XORG_FONT_CHECK_ISO8859_7],[
- AC_ARG_ENABLE(iso8859-7,
- AS_HELP_STRING([--disable-iso8859-7],
- [Build ISO8859-7 fonts (default: yes)]),
- [ISO8859_7=$enableval],
- [ISO8859_7=yes])
- AC_MSG_CHECKING([whether to build ISO8859-7 fonts])
- AC_MSG_RESULT([$ISO8859_7])
- AM_CONDITIONAL(ISO8859_7, [test "x$ISO8859_7" = xyes])
-])
-
-AC_DEFUN([XORG_FONT_CHECK_ISO8859_8],[
- AC_ARG_ENABLE(iso8859-8,
- AS_HELP_STRING([--disable-iso8859-8],
- [Build ISO8859-8 fonts (default: yes)]),
- [ISO8859_8=$enableval],
- [ISO8859_8=yes])
- AC_MSG_CHECKING([whether to build ISO8859-8 fonts])
- AC_MSG_RESULT([$ISO8859_8])
- AM_CONDITIONAL(ISO8859_8, [test "x$ISO8859_8" = xyes])
-])
-
-AC_DEFUN([XORG_FONT_CHECK_ISO8859_9],[
- AC_ARG_ENABLE(iso8859-9,
- AS_HELP_STRING([--disable-iso8859-9],
- [Build ISO8859-9 fonts (default: yes)]),
- [ISO8859_9=$enableval],
- [ISO8859_9=yes])
- AC_MSG_CHECKING([whether to build ISO8859-9 fonts])
- AC_MSG_RESULT([$ISO8859_9])
- AM_CONDITIONAL(ISO8859_9, [test "x$ISO8859_9" = xyes])
-])
-
-AC_DEFUN([XORG_FONT_CHECK_ISO8859_10],[
- AC_ARG_ENABLE(iso8859-10,
- AS_HELP_STRING([--disable-iso8859-10],
- [Build ISO8859-10 fonts (default: yes)]),
- [ISO8859_10=$enableval],
- [ISO8859_10=yes])
- AC_MSG_CHECKING([whether to build ISO8859-10 fonts])
- AC_MSG_RESULT([$ISO8859_10])
- AM_CONDITIONAL(ISO8859_10, [test "x$ISO8859_10" = xyes])
-])
-
-AC_DEFUN([XORG_FONT_CHECK_ISO8859_11],[
- AC_ARG_ENABLE(iso8859-11,
- AS_HELP_STRING([--disable-iso8859-11],
- [Build ISO8859-11 fonts (default: yes)]),
- [ISO8859_11=$enableval],
- [ISO8859_11=yes])
- AC_MSG_CHECKING([whether to build ISO8859-11 fonts])
- AC_MSG_RESULT([$ISO8859_11])
- AM_CONDITIONAL(ISO8859_11, [test "x$ISO8859_11" = xyes])
-])
-
-AC_DEFUN([XORG_FONT_CHECK_ISO8859_12],[
- AC_ARG_ENABLE(iso8859-12,
- AS_HELP_STRING([--disable-iso8859-12],
- [Build ISO8859-12 fonts (default: yes)]),
- [ISO8859_12=$enableval],
- [ISO8859_12=yes])
- AC_MSG_CHECKING([whether to build ISO8859-12 fonts])
- AC_MSG_RESULT([$ISO8859_12])
- AM_CONDITIONAL(ISO8859_12, [test "x$ISO8859_12" = xyes])
-])
-
-AC_DEFUN([XORG_FONT_CHECK_ISO8859_13],[
- AC_ARG_ENABLE(iso8859-13,
- AS_HELP_STRING([--disable-iso8859-13],
- [Build ISO8859-13 fonts (default: yes)]),
- [ISO8859_13=$enableval],
- [ISO8859_13=yes])
- AC_MSG_CHECKING([whether to build ISO8859-13 fonts])
- AC_MSG_RESULT([$ISO8859_13])
- AM_CONDITIONAL(ISO8859_13, [test "x$ISO8859_13" = xyes])
-])
-
-AC_DEFUN([XORG_FONT_CHECK_ISO8859_14],[
- AC_ARG_ENABLE(iso8859-14,
- AS_HELP_STRING([--disable-iso8859-14],
- [Build ISO8859-14 fonts (default: yes)]),
- [ISO8859_14=$enableval],
- [ISO8859_14=yes])
- AC_MSG_CHECKING([whether to build ISO8859-14 fonts])
- AC_MSG_RESULT([$ISO8859_14])
- AM_CONDITIONAL(ISO8859_14, [test "x$ISO8859_14" = xyes])
-])
-
-AC_DEFUN([XORG_FONT_CHECK_ISO8859_15],[
- AC_ARG_ENABLE(iso8859-15,
- AS_HELP_STRING([--disable-iso8859-15],
- [Build ISO8859-15 fonts (default: yes)]),
- [ISO8859_15=$enableval],
- [ISO8859_15=yes])
- AC_MSG_CHECKING([whether to build ISO8859-15 fonts])
- AC_MSG_RESULT([$ISO8859_15])
- AM_CONDITIONAL(ISO8859_15, [test "x$ISO8859_15" = xyes])
-])
-
-AC_DEFUN([XORG_FONT_CHECK_ISO8859_16],[
- AC_ARG_ENABLE(iso8859-16,
- AS_HELP_STRING([--disable-iso8859-16],
- [Build ISO8859-16 fonts (default: yes)]),
- [ISO8859_16=$enableval],
- [ISO8859_16=yes])
- AC_MSG_CHECKING([whether to build ISO8859-16 fonts])
- AC_MSG_RESULT([$ISO8859_16])
- AM_CONDITIONAL(ISO8859_16, [test "x$ISO8859_16" = xyes])
-])
-
-AC_DEFUN([XORG_FONT_CHECK_JISX0201],[
- AC_ARG_ENABLE(jisx0201,
- AS_HELP_STRING([--disable-jisx0201],
- [Build JISX0201 fonts (default: yes)]),
- [JISX0201=$enableval],
- [JISX0201=yes])
- AC_MSG_CHECKING([whether to build JISX0201 fonts])
- AC_MSG_RESULT([$JISX0201])
- AM_CONDITIONAL(JISX0201, [test "x$JISX0201" = xyes])
-])
-
-AC_DEFUN([XORG_FONT_CHECK_KOI8_R],[
- AC_ARG_ENABLE(koi8-r,
- AS_HELP_STRING([--disable-koi8-r],
- [Build KOI8-R fonts (default: yes)]),
- [KOI8_R=$enableval],
- [KOI8_R=yes])
- AC_MSG_CHECKING([whether to build KOI8-R fonts])
- AC_MSG_RESULT([$KOI8_R])
- AM_CONDITIONAL(KOI8_R, [test "x$KOI8_R" = xyes])
-])
diff --git a/fontutil.m4.in b/fontutil.m4.in
new file mode 100644
index 0000000..ca503e1
--- /dev/null
+++ b/fontutil.m4.in
@@ -0,0 +1,300 @@
+dnl @configure_input@
+dnl
+dnl This file comes from X.Org's @PACKAGE_STRING@
+dnl
+dnl Copyright 2005 Red Hat, Inc
+dnl
+dnl Permission to use, copy, modify, distribute, and sell this software and its
+dnl documentation for any purpose is hereby granted without fee, provided that
+dnl the above copyright notice appear in all copies and that both that
+dnl copyright notice and this permission notice appear in supporting
+dnl documentation.
+dnl
+dnl The above copyright notice and this permission notice shall be included
+dnl in all copies or substantial portions of the Software.
+dnl
+dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS
+dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
+dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.
+dnl IN NO EVENT SHALL THE OPEN GROUP BE LIABLE FOR ANY CLAIM, DAMAGES OR
+dnl OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,
+dnl ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR
+dnl OTHER DEALINGS IN THE SOFTWARE.
+dnl
+dnl Except as contained in this notice, the name of the copyright holders shall
+dnl not be used in advertising or otherwise to promote the sale, use or
+dnl other dealings in this Software without prior written authorization
+dnl from the copyright holders.
+dnl
+dnl --------------------------------------------------------------------
+dnl
+dnl Copyright 2009 Sun Microsystems, Inc. All rights reserved.
+dnl
+dnl Permission is hereby granted, free of charge, to any person obtaining a
+dnl copy of this software and associated documentation files (the
+dnl "Software"), to deal in the Software without restriction, including
+dnl without limitation the rights to use, copy, modify, merge, publish,
+dnl distribute, and/or sell copies of the Software, and to permit persons
+dnl to whom the Software is furnished to do so, provided that the above
+dnl copyright notice(s) and this permission notice appear in all copies of
+dnl the Software and that both the above copyright notice(s) and this
+dnl permission notice appear in supporting documentation.
+dnl
+dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS
+dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
+dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT
+dnl OF THIRD PARTY RIGHTS. IN NO EVENT SHALL THE COPYRIGHT HOLDER OR
+dnl HOLDERS INCLUDED IN THIS NOTICE BE LIABLE FOR ANY CLAIM, OR ANY SPECIAL
+dnl INDIRECT OR CONSEQUENTIAL DAMAGES, OR ANY DAMAGES WHATSOEVER RESULTING
+dnl FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN ACTION OF CONTRACT,
+dnl NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF OR IN CONNECTION
+dnl WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
+dnl
+dnl Except as contained in this notice, the name of a copyright holder
+dnl shall not be used in advertising or otherwise to promote the sale, use
+dnl or other dealings in this Software without prior written authorization
+dnl of the copyright holder.
+
+# XORG_FONT_MACROS_VERSION(required-version)
+# ------------------------------------------
+# Minimum version: 1.1.0
+#
+# If you're using a macro added in Version 1.1 or newer, include this in
+# your configure.ac with the minimum required version, such as:
+# XORG_FONT_MACROS_VERSION(1.1)
+#
+# To ensure that this macro is defined, also add:
+# m4_ifndef([XORG_FONT_MACROS_VERSION],
+# [m4_fatal([must install X.Org font-util 1.1 or later before running autoconf/autogen])])
+#
+#
+# See the "minimum version" comment for each macro you use to see what
+# version you require.
+m4_defun([XORG_FONT_MACROS_VERSION],[
+m4_define([vers_have], [@VERSION@])
+m4_define([maj_have], m4_substr(vers_have, 0, m4_index(vers_have, [.])))
+m4_define([maj_needed], m4_substr([$1], 0, m4_index([$1], [.])))
+m4_if(m4_cmp(maj_have, maj_needed), 0,,
+ [m4_fatal([font-util major version ]maj_needed[ is required but ]vers_have[ found])])
+m4_if(m4_version_compare(vers_have, [$1]), -1,
+ [m4_fatal([font-util version $1 or higher is required but ]vers_have[ found])])
+m4_undefine([vers_have])
+m4_undefine([maj_have])
+m4_undefine([maj_needed])
+]) # XORG_FONT_MACROS_VERSION
+
+# XORG_FONT_CHECK_{maps}()
+# ------------------------
+# Minimum version: 1.0.0
+# These macros add --enable/disable-{maps} where {maps} are ISO8859-*,
+# JISX0201 or KOI8_R. By default, they are all enabled.
+
+AC_DEFUN([XORG_FONT_CHECK_ISO8859_1], [XORG_FONT_CHECK_ENCODING(ISO8859-1)])
+AC_DEFUN([XORG_FONT_CHECK_ISO8859_2], [XORG_FONT_CHECK_ENCODING(ISO8859-2)])
+AC_DEFUN([XORG_FONT_CHECK_ISO8859_3], [XORG_FONT_CHECK_ENCODING(ISO8859-3)])
+AC_DEFUN([XORG_FONT_CHECK_ISO8859_4], [XORG_FONT_CHECK_ENCODING(ISO8859-4)])
+AC_DEFUN([XORG_FONT_CHECK_ISO8859_5], [XORG_FONT_CHECK_ENCODING(ISO8859-5)])
+AC_DEFUN([XORG_FONT_CHECK_ISO8859_6], [XORG_FONT_CHECK_ENCODING(ISO8859-6)])
+AC_DEFUN([XORG_FONT_CHECK_ISO8859_7], [XORG_FONT_CHECK_ENCODING(ISO8859-7)])
+AC_DEFUN([XORG_FONT_CHECK_ISO8859_8], [XORG_FONT_CHECK_ENCODING(ISO8859-8)])
+AC_DEFUN([XORG_FONT_CHECK_ISO8859_9], [XORG_FONT_CHECK_ENCODING(ISO8859-9)])
+AC_DEFUN([XORG_FONT_CHECK_ISO8859_10],[XORG_FONT_CHECK_ENCODING(ISO8859-10)])
+AC_DEFUN([XORG_FONT_CHECK_ISO8859_11],[XORG_FONT_CHECK_ENCODING(ISO8859-11)])
+AC_DEFUN([XORG_FONT_CHECK_ISO8859_12],[XORG_FONT_CHECK_ENCODING(ISO8859-12)])
+AC_DEFUN([XORG_FONT_CHECK_ISO8859_13],[XORG_FONT_CHECK_ENCODING(ISO8859-13)])
+AC_DEFUN([XORG_FONT_CHECK_ISO8859_14],[XORG_FONT_CHECK_ENCODING(ISO8859-14)])
+AC_DEFUN([XORG_FONT_CHECK_ISO8859_15],[XORG_FONT_CHECK_ENCODING(ISO8859-15)])
+AC_DEFUN([XORG_FONT_CHECK_ISO8859_16],[XORG_FONT_CHECK_ENCODING(ISO8859-16)])
+AC_DEFUN([XORG_FONT_CHECK_JISX0201], [XORG_FONT_CHECK_ENCODING(JISX0201)])
+AC_DEFUN([XORG_FONT_CHECK_KOI8_R], [XORG_FONT_CHECK_ENCODING(KOI8-R)])
+
+# XORG_FONT_CHECK_ENCODING(encoding)
+# ----------------------------------
+# Minimum version: 1.1.0
+# This macro adds --enable/disable-<encoding>, enabled by default.
+# It replaced individual copies of this code in the above macros in 1.1.
+# Currently assumes encoding names will be all upper-case - add m4_toupper
+# calls if this is not true in the future.
+
+AC_DEFUN([XORG_FONT_CHECK_ENCODING],[
+ AC_ARG_ENABLE(m4_tolower($1),
+ AS_HELP_STRING(m4_join([-], [--disable], m4_tolower($1)),
+ [Build $1 fonts (default: yes)]),
+ [AS_TR_SH($1)=$enableval], [AS_TR_SH($1)=yes])
+ AC_MSG_CHECKING([whether to build $1 fonts])
+ AC_MSG_RESULT($[AS_TR_SH($1)])
+ AM_CONDITIONAL(AS_TR_SH($1), [test "x$AS_TR_SH($1)" = xyes])
+]) # XORG_FONT_CHECK_ENCODING
+
+# XORG_FONT_CHECK_ENCODING_LIST(encoding1 encoding2....)
+# -----------------------------------------------------
+# Minimum version: 1.1.0
+# Call XORG_FONT_CHECK_ENCODING for multiple encodings at once
+
+AC_DEFUN([XORG_FONT_CHECK_ENCODING_LIST],[
+ m4_foreach_w([enc], [$1], [XORG_FONT_CHECK_ENCODING(enc)])
+]) # XORG_FONT_CHECK_ENCODING_LIST
+
+# XORG_FONT_REQUIRED_PROG(VARNAME, progname)
+# ------------------------------------------
+# Minimum version: 1.1.0
+#
+# Simple wrapper around AC_PATH_PROG that errors if not found
+#
+
+AC_DEFUN([XORG_FONT_REQUIRED_PROG],[
+ AC_PATH_PROG($1, $2)
+ if test x"$1" = x; then
+ AC_MSG_ERROR([$2 is required to build $PACKAGE_NAME.])
+ fi
+])
+
+
+# XORG_FONT_FCCACHE()
+# -------------------
+# Minimum version: 1.1.0
+#
+# Set FCCACHE to path to fc-cache (fontconfig cache builder) if found
+# Set RUN_FCCACHE to a rule suitable for substituting into a makefile
+# to run fc-cache if found and not installing to $DESTDIR
+#
+# fc-cache is optional, not required, and should be skipped when making
+# packages (installing to $DESTDIR).
+#
+AC_DEFUN([XORG_FONT_FCCACHE],[
+ AC_PATH_PROG(FCCACHE, fc-cache)
+ FCCACHE_WARN='echo "** Warning: fonts.cache not built" ; echo "** Generate this file manually on host system using fc-cache"'
+ if test x"$FCCACHE" = x ; then
+ RUN_FCCACHE="${FCCACHE_WARN}"
+ else
+ RUN_FCCACHE='@(if test -z "$(DESTDIR)"; then echo $(FCCACHE) $(fontdir); $(FCCACHE) $(fontdir); else'
+ RUN_FCCACHE="${RUN_FCCACHE} ${FCCACHE_WARN} ; fi)"
+ fi
+ AC_SUBST([RUN_FCCACHE])
+])
+
+
+# XORG_FONT_COMMON_UTILS()
+# ------------------------
+# Minimum version: 1.1.0
+#
+# Call XORG_FONT_REQUIRED_PROG for programs needed for all font types
+
+AC_DEFUN([XORG_FONT_COMMON_UTILS],[
+ XORG_FONT_FCCACHE
+ XORG_FONT_REQUIRED_PROG(MKFONTDIR, mkfontdir)
+])
+
+# XORG_FONT_SCALED_UTILS()
+# ------------------------
+# Minimum version: 1.1.0
+#
+# Call XORG_FONT_REQUIRED_PROG for programs needed for scalable fonts
+# (TrueType, OpenType, Type1)
+
+AC_DEFUN([XORG_FONT_SCALED_UTILS],[
+ XORG_FONT_COMMON_UTILS
+ XORG_FONT_REQUIRED_PROG(MKFONTSCALE, mkfontscale)
+])
+
+# XORG_FONT_BDF_UTILS()
+# ---------------------
+# Minimum version: 1.1.0
+#
+# Call XORG_FONT_REQUIRED_PROG for programs needed for BDF format bitmap fonts
+# Also call XORG_FONT_CHECK_COMPRESSION to determine how to compress the
+# PCF output files created by bdftopcf
+
+AC_DEFUN([XORG_FONT_BDF_UTILS],[
+ XORG_FONT_COMMON_UTILS
+ XORG_FONT_REQUIRED_PROG(BDFTOPCF, bdftopcf)
+ XORG_FONT_CHECK_COMPRESSION
+])
+
+# XORG_FONT_CHECK_COMPRESSION()
+# -----------------------------
+# Minimum version: 1.1.0
+#
+# Offer a --with-compression flag to control what compression method is
+# used for pcf font files. Offers all the methods currently supported
+# by libXfont, including no compression.
+
+AC_DEFUN([XORG_FONT_CHECK_COMPRESSION],[
+ AC_MSG_CHECKING([font compression method])
+ AC_ARG_WITH(compression,
+ [AS_HELP_STRING([--with-compression=<no|compress|gzip|bzip2>],
+ [compression method to use on pcf fonts])],
+ [compression="$withval"], [compression="yes"])
+ if test x"$compression" = "xyes" ; then
+ compression="gzip"
+ fi
+ AC_MSG_RESULT([${compression}])
+ case ${compression} in
+ *compress) COMPRESS_SUFFIX=".Z" ;;
+ *gzip) COMPRESS_SUFFIX=".gz" ;;
+ *bzip2) COMPRESS_SUFFIX=".bz2" ;;
+ no|none) COMPRESS_SUFFIX="" ; COMPRESS="cat" ;;
+ *) AC_MSG_ERROR([${compression} is not a supported compression method]) ;;
+ esac
+ if test x"$COMPRESS_SUFFIX" != "x" ; then
+ XORG_FONT_REQUIRED_PROG(COMPRESS, ${compression})
+ fi
+ AC_SUBST([COMPRESS_SUFFIX])
+])
+
+# XORG_FONT_UCS2ANY()
+# -------------------
+# Minimum version: 1.1.0
+#
+# Call XORG_FONT_REQUIRED_PROG for ucs2any program needed for splitting
+# Unicode-encoded BDF format bitmap fonts into subsets for older encodings.
+# Also call pkg-config to find the directory with the encoding files needed
+# by ucs2any, and export it as MAPFILES_PATH to the Makefiles
+
+AC_DEFUN([XORG_FONT_UCS2ANY],[
+ XORG_FONT_REQUIRED_PROG(UCS2ANY, ucs2any)
+ PKG_CHECK_MODULES(MAPS, [fontutil])
+ AC_MSG_CHECKING([for ucs2any encoding data files])
+ MAPFILES_PATH=`pkg-config --variable=mapdir fontutil`
+ AC_SUBST(MAPFILES_PATH)
+ AC_MSG_RESULT([${MAPFILES_PATH}])
+])
+
+
+
+# XORG_FONTDIR(subdir)
+# --------------------
+# Minimum version: 1.1.0
+#
+# Offer a --with-fontdir flag to control directory for font installation
+# Default is the specified subdir of the font parent directory.
+# Font parent directory is the first found from:
+# --with-fontparentdir
+# pkg-config --variable=fontdir fontutil
+# ${datadir}/fonts/X11
+
+AC_DEFUN([XORG_FONTDIR],[
+ dnl Ensure $PKG_CONFIG is set first
+ AC_REQUIRE([PKG_PROG_PKG_CONFIG])
+
+ AC_MSG_CHECKING([where to install fonts])
+ AC_ARG_WITH(fontparentdir,
+ AS_HELP_STRING([--with-fontparentdir=<pathname>],
+ [Path to parent directory to install fonts]),
+ [fontparentdir="$withval"])
+ # if --with-fontparentdir not specified...
+ if test "x${fontparentdir}" = "x"; then
+ fontparentdir=`$PKG_CONFIG --variable=fontdir fontutil`
+ fi
+ # ...and if pkg-config didn't find fontdir in fontutil.pc...
+ if test "x${fontparentdir}" = "x"; then
+ fontparentdir="${datadir}/fonts/X11"
+ fi
+
+ AC_ARG_WITH(fontdir,
+ AS_HELP_STRING([--with-fontdir=<pathname>],
+ [Path to install fonts (default: <fontparentdir>/$1)]),
+ [FONTDIR="$withval"], [FONTDIR="$fontparentdir/$1"])
+ AC_SUBST(FONTDIR)
+ AC_MSG_RESULT([${FONTDIR}])
+])
diff --git a/fontutil.pc.in b/fontutil.pc.in
index c0fc1b4..662f01c 100644
--- a/fontutil.pc.in
+++ b/fontutil.pc.in
@@ -1,6 +1,9 @@
prefix=@prefix@
exec_prefix=@exec_prefix@
libdir=@libdir@
+datarootdir=@datarootdir@
+datadir=@datadir@
+fontdir=@FONTDIR@
mapdir=@MAPDIR@
Name: FontUtil
--
1.5.6.5
More information about the xorg-devel
mailing list